Thread: [Tutorial] script auto-update ddns via no-ip.com

gan saya ada juga ddns yang lain mohon bantuan scriptnya dari minidns.net, dan juga untukbuat tunnel vpn dengan ipsec apakah bisa...?

Originally Posted by marlon.s

gan saya ada juga ddns yang lain mohon bantuan scriptnya dari minidns.net, dan juga untukbuat tunnel vpn dengan ipsec apakah bisa...?

untuk ddns nya

Code:

# DNS miniDNS.net automatic DNS updates
# Informasi account di minidns.com
:global usernoip "<isi username account di sini>"
:global passnoip "<isi password disini>"
:global hostnamenoip "<ganti dengan hostname lengkap di sini>"
# Edit variabel selesai di sini

:global previousIP

# Print di log untuk debug
:log info "miniDNS: Updating dynamic IP on DNS for host $hostnamenoip"
:log info "miniDNS: Pass $passnoip"
:log info "miniDNS: Last IP $previousIP"

# mendapatkan IP public di intenet, bisa juga dengan script PHP jika punya hosting support PHP
/tool fetch url="http://checkip.dyndns.org/" dst-path="/miniDNS.html"

:local hasil [/file get miniDNS.html contents]

# Edit untuk mendapatkan IP terbaru
:local hasilLen [:len $hasil]
:local startLoc [:find $hasil ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $hasil "</body>" -1]
:global currentIP [:pick $hasil $startLoc $endLoc]
:log info "miniDNS: IP sekarang $currentIP"

# persiapan update
:local str "areg.php?opcode=ADD&host=$hostnamenoip&username=$usernoip&password=$passnoip&ip=$currentIP"

:if ($currentIP != $previousIP) do={
:log info "miniDNS: Dibutuhkan Update"
:set previousIP $currentIP
:log info "miniDNS: Kirim Update $currentIP"
:log info [:put [/tool fetch user="$usernoip" password="$passnoip" url="http://www.minidns.net/$str" dst-path="/$hostnamenoip"]]
:log info "miniDNS: Host $hostnamenoip telah terupdate di miniDNS dengan IP $currentIP"
}  else={
:log info "miniDNS: IP sebelumnya $previousIP dan IP sekarang $currentIP sama, tidak dibutuhkan update"
}

tested on mikrotik v5.16, jangan lupa untuk schedule-nya, nanti ditaroh depan jika berfungsi.

untuk tunnel ipsec setahu saya paling mudah menggunakan ip address public STATIS di kedua sisi. jika dinamis maka perlu script tersendiri (diluar bahasan ini). biasanya saya bikin ipsec untuk mengamankan IPIP tunnel.

Terima kasih banyak gan udah erhasil di kenal juga....
minta petunjuka nih gan untuk buat ipsec tunnel VPN dynamic gimana caranya gan....?

Originally Posted by marlon.s

gan saya ada juga ddns yang lain mohon bantuan scriptnya dari minidns.net, dan juga untukbuat tunnel vpn dengan ipsec apakah bisa...?

gan pos_ronda bisa satu account di no-ip.com di buat lebih darisatu host

Originally Posted by GAS

gan pos_ronda bisa satu account di no-ip.com di buat lebih darisatu host

ini tanya apa info gan? 1 acc no-ip bisa sampai 5 host. tinggal ganti nama host di :global hostnamenoip

sangat membantu nih postingan, berhubung skrng ISP Andalan Indonesia ini tidak lagi menerapkan "IP Public static" dikarenakan ada fitur baru speedy yaitu Home Monitoring, jadinya ini adalah alternatif, tapi kalau seandainya NO.Ip jg udh mulai berbayar kyk DynDNS dlu, apa boleh buat tinggal nambah 30rb/bln dah dari sapidy,,,

sangat membantu, terima kasih semua masta"

Originally Posted by ViperCiamiK

Bro, saya sudah coba config yang di atas, menggunakan router os v5.11
pas saya pantau semuanya sih running normal,
tapi ternyata data yang di noip tersebut gak ke update di sana nya...

Terus kemudian saya coba kutak kutik om google lagi, eh ketemu script ini... spertinya sih modifan dari script nya si dydns dulu juga yang di rubah ke noip, tapi pas saya pake script itu jalan...
Mungkin bro punya bisa di perbaiki?

Berikut cuplikan dari script yang jalan:

Code:

# Set needed variables
:global username "your-username"
:global password "your-password"
:global hostname "your-hostname"
:global wanInt "your-Interface"
:global noipForce
:global previousIP2

# print some debug info
#:log info ("DDNS: username = $username")
#:log info ("DDNS: password = $password")
:log info ("DDNS: hostname = $hostname")
:log info ("DDNS: previousIP = $previousIP2")


# Grab the current IP address on that interface.
:global ddnsip [/ip address get [/ip address find interface="$wanInt"] address]
:global currentIP [:pick $ddnsip 0 [:find $ddnsip "/"]]

#:log info ("DDNS: ddnsip = $ddnsip")
:log info ("DDNS: currentIP = $currentIP")

# Remove the # on next line to force an update every single time - useful for debugging, but you could end up getting blacklisted by No-IP!
#:set noipForce true

# Determine if no-ip update is needed
# more no-ip updater request details available at http://www.no-ip.com/integrate/request/
:if (($currentIP != $previousIP2) || ($noipForce = true)) do={
    :set noipForce false
    :set previousIP2 $currentIP
    :log info ("DDNS: No-IP update needed")
    :log info ("DDNS: Start of Fetch")
global tmp [/tool fetch mode=http port=80 address=dynupdate.no-ip.com host=dynupdate.no-ip.com src-path="/nic/update?hostname=$hostname&myip=$currentIP" user=$username password=$password dst-path="/noip2.txt"]
    :log info ("DDNS: End of Fetch")
    :global result [/file get noip2.txt contents]
    :log info ("DDNS: No-IP Update Result: $result")
    :put ("No-IP Update Result: $result")
# Update HE.net Tunnel
#   :execute script=HE-NET
} else={
    :log info ("DDNS: No No-IP update needed")
}

Semoga dapat membantu

benar2 mantap, dari semua script yang saya coba ini yang berhasil working 1000%
makasih mastah

gan buat Mikrotik RB450G winbox V4.17 kok g bisa ya,,,,
d log nya
script info DNSNoIP: Last IP

Mantep nih tutor, berguna buat yg gak punya IP Public Static.

mantab mas saya dah test berhasil, jika mau pakai dyn ini penyedia dns garatis juga gmn scriptnya bang.

coba bantu...

Saya makai punya teman di forum sini jalan kok sampai sekarang.
nich threadnya

Semoga membantu

Originally Posted by pos_ronda

Jika router mikrotik mendapat IP Address Public Dynamic maka,
berikut ini adalah script untuk update ip via no-ip.com
pertama-tama, tentu saja daftar di
(daptar nya kalau mau lewat referal gw, tinggal klik link tersebut, kalau gak berkenan ya gpp)

registrasi dan add host di no-ip.com
1. registrasi seperti biasa, isi first name, last name, email, username, password, dll. (yang di bold harap diperhatikan)
2. setelah registrasi selesai, login dengan username dan password.
3. Pilih Hosts/Redirects, lanjut dengan pilih Add Host
4. Isikan nama hostname dan pilih domain nya. (lagi-lagi yang di bold harap diperhatikan)
5. IP Address diisikan : 127.0.0.1
6. Setelah itu klik Create Host pada bagian bawah form.
7. Pembuatan hostname selesai. Tunggu satu menit untuk diupdate. Sementara itu kita buat scriptnya..

masuk winbox, pilih system--schedule--add

Name: sch-ddns-NoIP
Start Date: Jan/01/1970
Start Time: startup
Interval : 00:05:00 # tiap lima menit

Isikan on-event script berikut:

ubah yang garis bawah dengan username, password, dan hostname lengkap dengan domainnya di no-ip (mis. fmi.zapto.org)
username, password, dan hostname terdapat pada bagian yang di bold di tutorial registrasi di atas.

Code:

# DNS no-ip automatic DNS updates
# Informasi account di no-ip.com
:global usernoip "<isi username account di sini>"
:global passnoip "<isi password disini>"
:global hostnamenoip "<ganti dengan hostname lengkap di sini>"
# Edit variabel selesai di sini

:global previousIP

# Print di log untuk debug
:log info "DNSNoIP: Updating dynamic IP on DNS for host $hostnamenoip"
:log info "DNSNoIP: Pass $passnoip"
:log info "DNSNoIP: Last IP $previousIP"

# mendapatkan IP public di intenet, bisa juga dengan script PHP jika punya hosting support PHP
/tool fetch url="http://checkip.dyndns.org/" dst-path="/ddnsnoip.html"

:local hasil [/file get ddnsnoip.html contents]

# Edit untuk mendapatkan IP terbaru
:local hasilLen [:len $hasil]
:local startLoc [:find $hasil ": " -1]
:set startLoc ($startLoc + 2)
:local endLoc [:find $hasil "</body>" -1]
:global currentIP [:pick $hasil $startLoc $endLoc]
:log info "DNSNoIP: IP sekarang $currentIP"

# persiapan update
:local str "/nic/update?hostname=$hostnamenoip&myip=$currentIP"

:if ($currentIP != $previousIP) do={
:log info "DNSNoIP: Dibutuhkan Update"
:set previousIP $currentIP
:log info "DNSNoIP: Kirim Update $currentIP"
:log info [:put [/tool fetch user="$usernoip" password="$passnoip" url="http://dynupdate.no-ip.com/$str" dst-path="/$hostnamenoip"]]
:log info "DNSNoIP: Host $hostnamenoip telah terupdate di DNSNoIP dengan IP $currentIP"
}  else={
:log info "DNSNoIP: IP sebelumnya $previousIP dan IP sekarang $currentIP sama, tidak dibutuhkan update"
}

untuk minidns.net ada di

cara panggil router dari internet tinggal isikan hostname pada winbox (connect to..).

Kritik dan Saran silakan.
Semoga membantu

NB: Jika ada free DDNS yang lain, bisa saya bantu modif untuk script di atas.

It WORKS Gan! Manteb banget.
sekian banyak sekript yg ane gunakan dr hasil googling baru ini yg maknyus.. thanks masta
btw Gan.. ane coba akses hostnya lewat broswing tp yg muncul IIS. sample hostnya xxxxxx.zapto.org/userman dan xxxxxx.zapto.org/webfig.
Skali lg ane ucapin makasih banyak2 buat Gan Masta.

sudah ada yang berhasil Dynamic DNS di Mikrotik V6.xx?

Bagi donk